// This file is part of www.nand2tetris.org
// and the book "The Elements of Computing Systems"
// by Nisan and Schocken, MIT Press.
// File name: projects/05/Memory.hdl

/**
 * The complete address space of the Hack computer's memory,
 * including RAM and memory-mapped I/O. 
 * The chip facilitates read and write operations, as follows:
 *     Read:  out(t) = Memory[address(t)](t)
 *     Write: if load(t-1) then Memory[address(t-1)](t) = in(t-1)
 * In words: the chip always outputs the value stored at the memory 
 * location specified by address. If load==1, the in value is loaded 
 * into the memory location specified by address. This value becomes 
 * available through the out output from the next time step onward.
 * Address space rules:
 * Only the upper 16K+8K+1 words of the Memory chip are used. 
 * Access to address>0x6000 is invalid. Access to any address in 
 * the range 0x4000-0x5FFF results in accessing the screen memory 
 * map. Access to address 0x6000 results in accessing the keyboard 
 * memory map. The behavior in these addresses is described in the 
 * Screen and Keyboard chip specifications given in the book.
 */

CHIP Memory {
    IN in[16], load, address[15];
    OUT out[16];

    PARTS:
    // Note: I just realized that pin names can be mixed-case, so I've changed
    // my pin naming convention (I'd _still_ prefer to use underscores if they
    // were allowed...)

    // chooses whether value of load goes to RAM16 or memory-mapped screen
    DMux(in=load, sel=address[14], a=loadToRAM, b=loadToScreen);

    RAM16K(in=in, address=address[0..13], load=loadToRAM, out=ramOut);
    Screen(in=in, address=address[0..12], load=loadToScreen, out=screenOut);
    Keyboard(out=keyboardOut);

    // choose between screen and keyboard (selection determined by whether both
    // address[13] and address[14] are set
    // (An aside: this approach has the added benefit that accessing "invalid
    // addresses", which are above 0x6000, simply results in accessing the
    // keyboard. I feel clever)
    And(a=address[13], b=address[14], out=screenOrKeyboard);
    Mux16(a=screenOut, b=keyboardOut, sel=screenOrKeyboard, out=peripheralOut);

    // choose between RAM and screen/keyboard (determined by address[14]);
    Mux16(a=ramOut, b=peripheralOut, sel=address[14], out=out);
}