projects/02/ALU.hdl
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 |
// This file is part of www.nand2tetris.org
// and the book "The Elements of Computing Systems"
// by Nisan and Schocken, MIT Press.
// File name: projects/02/ALU.hdl
/**
* The ALU (Arithmetic Logic Unit).
* Computes one of the following functions:
* x+y, x-y, y-x, 0, 1, -1, x, y, -x, -y, !x, !y,
* x+1, y+1, x-1, y-1, x&y, x|y on two 16-bit inputs,
* according to 6 input bits denoted zx,nx,zy,ny,f,no.
* In addition, the ALU computes two 1-bit outputs:
* if the ALU output == 0, zr is set to 1; otherwise zr is set to 0;
* if the ALU output < 0, ng is set to 1; otherwise ng is set to 0.
*/
// Implementation: the ALU logic manipulates the x and y inputs
// and operates on the resulting values, as follows:
// if (zx == 1) set x = 0 // 16-bit constant
// if (nx == 1) set x = !x // bitwise not
// if (zy == 1) set y = 0 // 16-bit constant
// if (ny == 1) set y = !y // bitwise not
// if (f == 1) set out = x + y // integer 2's complement addition
// if (f == 0) set out = x & y // bitwise and
// if (no == 1) set out = !out // bitwise not
// if (out == 0) set zr = 1
// if (out < 0) set ng = 1
CHIP ALU {
IN
x[16], y[16], // 16-bit inputs
zx, // zero the x input?
nx, // negate the x input?
zy, // zero the y input?
ny, // negate the y input?
f, // compute out = x + y (if 1) or x & y (if 0)
no; // negate the out output?
OUT
out[16], // 16-bit output
zr, // 1 if (out == 0), 0 otherwise
ng; // 1 if (out < 0), 0 otherwise
PARTS:
Mux16(a=x, b=false, sel=zx, out=x-or-zero);
Mux16(a=y, b=false, sel=zy, out=y-or-zero);
Not16(in=x-or-zero, out=not-xoz);
Not16(in=y-or-zero, out=not-yoz);
Mux16(a=x-or-zero, b=not-xoz, sel=nx, out=x-arg);
Mux16(a=y-or-zero, b=not-yoz, sel=ny, out=y-arg);
Add16(a=x-arg, b=y-arg, out=add-xy);
And16(a=x-arg, b=y-arg, out=and-xy);
Mux16(a=and-xy, b=add-xy, sel=f, out=func-out);
Not16(in=func-out, out=not-func-out);
Mux16(a=func-out, b=not-func-out, sel=no, out[0..7]=or8-in1,
out[8..15]=or8-in2, out[15]=ng,
out=out);
Or8Way(in=or8-in1, out=or8-1);
Or8Way(in=or8-in2, out= or8-2);
Or(a=or8-1, b=or8-2, out=not-zr);
Not(in=not-zr, out=zr);
}
|